基于ANSYS的混凝土裂缝数值模拟

/clear
/congif,nres,2000
/prep7
et,1,65,,,,,,,1
et,2,8
MP,EX,1,13585
MP,prxy,1,0.2
fc=14.3
ft=1.43
tb,concr,1
tbdata,,0.5,0.95,ft,-1
tb,miso,1,,11
tbpt,,0.0002,fc*0.19
tbpt,,0.0004,fc*0.36
tbpt,,0.0006,fc*0.51
tbpt,,0.0008,fc*0.64
tbpt,,0.0010,fc*0.75
tbpt,,0.0012,fc*0.84
tbpt,,0.0014,fc*0.91
tbpt,,0.0016,fc*0.96
tbpt,,0.0018,fc*0.99
tbpt,,0.0020,fc
tbpt,,0.0033,fc*0.85

mp,ex,2,2.0e5
mp,prxy,2,0.3
tb,biso,2
tbdata,,300,0

pi=acos(-1)
r,1,0.25*pi*16*16
r,2,0.25*pi*8*8
r,3,0.25*pi*8*8/2

blc4,,,150/2,300,2500/2


*do,i,1,8
wpoff,,,100
vsbw,all
*enddo
*do,i,1,7
wpoff,,,60
vsbw,all
*enddo
wpcsys,-1 !------------切割出箍筋位置

wpoff,,,50
vsbw,all !------------模拟150*100mm的钢片加载
wpcsys,-1
wprota,,-90
wpoff,,,30
vsbw,all
*do,i,1,3
wpoff,,,80
vsbw,all
*enddo

wpcsys,-1
wpoff,30
wprota,,,90
vsbw,all !-----------钢筋位置切割完毕

elemsiz=50

lsel,s,loc,x,30
lsel,r,loc,y,30
cm,zj1,line
latt,2,1,2
lesize,all,elemsiz

lsel,s,loc,x,30
lsel,r,loc,y,110
cm,zj2,line
latt,2,2,2
lesize,all,elemsiz

lsel,s,loc,x,30
lsel,r,loc,y,190
cm,zj3,line
latt,2,2,2
lesize,all,elemsiz

lsel,s,loc,x,30
lsel,r,loc,y,270
cm,zj4,line
latt,2,2,2
lesize,all,elemsiz !-------N1-N3 纵向钢筋建立完毕


lsel,s,tan1,z
lsel,r,loc,x,30,70
lsel,r,loc,y,30,270
lsel,u,loc,y,110
lsel,u,loc,y,190
lsel,u,loc,z,50
cm,gj,line
latt,2,2,2
lesize,all,elemsiz !-------对称位置外箍筋建立


lsel,s,loc,z,0
lsel,r,loc,y,30,270
lsel,r,loc,x,30,70
lsel,u,loc,y,110
lsel,u,loc,y,190
cm,gjb,line
latt,2,3,2
lesize,all,elemsiz !-------对称位置处箍筋建立@ 整体建立完毕
lsel,all

cmsel,s,zj1
cmsel,a,zj2
cmsel,a,zj3
cmsel,a,zj4
cmsel,a,gj
cmsel,a,gjb
cm,gj,line
lmesh,all
lsel,all !------------所有钢筋简历完毕 后可加eshape,1 eplot



vatt,1,,1
mshkey,1
esize,elemsiz
vmesh,all
allsel,all

lsel,s,loc,y,0
lsel,r,loc,z,1160
dl,all,,uy !------------100mm处做支撑
asel,s,loc,z,0
da,all,symm
asel,s,loc,x,75
da,all,symm !------------对称面施加对称约束
p0=13000
q0=p0/150/100
asel,s,loc,z,0,50
asel,r,loc,y,300
sfa,all,a,pres,q0
allsel,all !------------假定在钢片上施加90KN的力

/solu
antype,0
nsubst,100
outres,all,all
autos,on
neqit,50
cnvtol,u,,0.015
solve

/post1$set,last$pldisp,1
/device,vector,on$plcrack