Excel_VBA实例教程_查找单元格

Excel VBA实例教程查找单元格

1、使用Find方法

在Excel中使用查找对话框可以查找工作表中特定内容的单元格，而在VBA中则使用Find方法，如下面的代码所示。

01.Sub RngFind()

02. Dim StrFind As String

03. Dim Rng As Range

04. StrFind = InputBox("请输入要查找的值:")

05. If Trim(StrFind) <> "" Then

06. With Sheet1.Range("A:A")

07. Set Rng = .Find(What:=StrFind, _

08. After:=.Cells(.Cells.Count), _

09. LookIn:=xlValues, _

10. LookAt:=xlWhole, _

11. SearchOrder:=xlByRows, _

12. SearchDirection:=xlNext, _

13. MatchCase:=False)

14. If Not Rng Is Nothing Then

15. Application.Goto Rng, True

16. Else

17. MsgBox "没有找到该单元格!"

18. End If

19. End With

20. End If

21.End Sub

代码解析：

RngFind过程使用Find方法在工作表Sheet1的A列中查找InputBox函数对话框中所输入的值，并查找该值所在的第一个单元格。

第6到第13行代码在工作表Sheet1的A列中查找InputBox函数对话框中所输入的值。应用于Range对象的Find方法在区域中查找特定信息，并返回Range对象，该对象代表用于查找信息的第一个单元格。如果未发现匹配单元格，就返回Nothing，语法如下：

01.expression.Find(What, After, LookIn, LookAt, SearchOrder, SearchDirection, MatchCase, MatchByte, SerchFormat)

复制代码参数expression是必需的，该表达式返回一个Range对象。

参数What是必需的，要搜索的数据，可为字符串或任意数据类型。

参数After是可选的，表示搜索过程将从其之后开始进行的单元格，必须是区域中的单个单元格。查找时是从该单元格之后开始的，直到本方法绕回到指定的单元格时，才对其进行搜索。如果未指定本参数，搜索将从区域的左上角单元格之后开始。

在本例中将After参数设置为A列的最后一个单元格，所以查找时从A1单元格开始搜索。

参数LookIn是可选的，信息类型。

参数LookAt是可选的，可为XlLookAt常量的xlWhole 或xlPart之一。

参数SearchOrder是可选的，可为XlSearchOrder常量的xlByRows或xlByColumns之一。

参数SearchDirection是可选的，搜索的方向，可为XlSearchDirection常量的xlNext或xlPrevious 之一。

参数MatchCase是可选的，若为True，则进行区分大小写的查找。默认值为False。

参数MatchByte是可选的，仅在选择或安装了双字节语言支持时使用。若为True，则双字节字符仅匹配双字节字符。若为False，则双字节字符可匹配其等价的单字节字符。

参数SerchFormat是可选的，搜索的格式。

每次使用Find方法后，参数LookIn、LookAt、SearchOrder 和MatchByte的设置将保存。如果下次调用Find方法时不指定这些参数的值，就使用保存的值。因此每次使用该方法时请明确设置这些参数。

如果工作表的A列中存在重复的数值，那么需要使用FindNext方法或FindPrevious方法进行重复搜索，如下面的代码所示。

01.Sub RngFindNext()

02. Dim StrFind As String

03. Dim Rng As Range

04. Dim FindAddress As String

05. StrFind = InputBox("请输入要查找的值:")

06. If Trim(StrFind) <> "" Then

07. With Sheet1.Range("A:A")

08. Set Rng = .Find(What:=StrFind, _

09. After:=.Cells(.Cells.Count), _

10. LookIn:=xlValues, _

11. LookAt:=xlWhole, _

12. SearchOrder:=xlByRows, _

13. SearchDirection:=xlNext, _

14. MatchCase:=False)

15. If Not Rng Is Nothing Then

16. FindAddress = Rng.Address

17. Do

18. Rng.Interior.ColorIndex = 6

19. Set Rng = .FindNext(Rng)

20. Loop While Not Rng Is Nothing And Rng.Address <> FindAddress

21. End If

22. End With

23. End If

24.End Sub

代码解析：

RngFindNext过程在工作表Sheet1的A列中查找InputBox函数对话框中所输入的值，并将查到单元格底色设置成黄色。

第8行到第17行代码使用Find方法在工作表Sheet1的A列中查找。

第16行代码将查找到的第一个单元格地址赋给字符串变量FindAddress。

第18行代码将查找到的单元格底色设置成黄色。

第19行代码使用FindNext方法进行重复搜索。FindNext方法继续执行用Find方法启动的搜索。查找下一个匹配相同条件的单元格并返回代表单元格的Range对象，语法如下：

01.expression.FindNext(After)

复制代码参数expression是必需的，返回一个Range对象。

参数After是可选的，指定一个单元格，查找将从该单元格之后开始。

第20行代码如果查找到的单元格地址等于字符串变量FindAddress所记录的地址，说明A列已

搜索完毕，结束查找过程。

运行RngFindNext过程，在InputBox函数输入框中输入“196.01”后结果如图1所示。

还可以使用FindPrevious方法进行重复搜索，FindPrevious方法的语法如下：

expression.FindPrevious(After)

FindPrevious方法和FindNext方法唯一的区别是FindPrevious方法查找匹配相同条件的前一个单元格而FindNext方法是查找匹配相同条件的下一个单元格。

2、使用Like运算符

使用Like运算符可以进行更为复杂的模式匹配查找，如下面的代码所示。

01.Sub RngLike()

02. Dim rng As Range

03. Dim a As Integer

04. a = 1

05. With Sheet2

06. .Range("A:A").ClearContents

07. For Each rng In .Range("B1:E1000")

08. If rng.Text Like "*a*" Then

09. .Range("A" & a) = rng.Text

10. a = a + 1

11. End If

12. Next

13. End With

14.End Sub

代码解析：

RngLike过程使用For Each...Next语句和Like运算符在单元格区域B1:E10000中搜索含有“a”字符的单元格，找到匹配单元格以后将单元格的值写入到A列中。

第6行代码使用ClearContents方法清除A列区域的数据。

第7行代码使用For Each...Next语句在单元格区域B1:E10000中循环。

第8行代码使用Like运算符在单元格区域B1:E10000中搜索含有“a”字符的单元格。

Like运算符用来比较两个字符串，语法如下：

01.result = string Like pattern

复制代码参数string是必需的，字符串表达式。

参数pattern是必需的，字符串表达式。

如果string与pattern匹配，则result为True；如果不匹配，则result为False。但是如果string或pattern 中有一个为Null，则result 为Null。

参数pattern可以使用通配符、字符串列表或字符区间的任何组合来匹配字符串。表格 5 1列出pattern中允许的字符以及它们与什么进行匹配。

pattern中的字符符合string中的字符

? 任何单一字符

* 零个或多个字符

# 任何一个数字(0–9)

[charlist] charlist中的任何单一字符

[!charlist] 不在charlist中的任何单一字符

表格1 pattern中的匹配字符串

第9行代码将找到的匹配单元格的值写入到A列中。

运行RngLike过程结果如图2所示。

integer li_ret

OLEObject ole_1 ,lole_Sheet ,lole_sheet1

ole_1 = CREATE OLEObject

li_ret=1

li_ret = ole_1.ConnectToObject( "excel.application ")

if li_ret <> 0 then

li_ret =ole_1.ConnectToNewObject( "excel.application ")

if li_ret <> 0 then

MessageBox( "提示 ", "EXCEL连接失败: "+String(li_ret))

return

end if

end if

ole_1.Workbooks.open( "E:\part.xls ")

lole_sheet = ole_1.Application.ActiveWorkbook.WorkSheets[1] ole_1.Application.Visible = true

lole_sheet1=lole_sheet.Range( "A1:A100 ").Find( "5003 ")

if isvalid(lole_sheet1) then

lole_sheet1.select()

else

messagebox( '提示 ', '没有找到数据 ')

end if

xlsub1.Range(ls_ran).Copy() //把所选内容复制到内存中