用ansys对一平面桁架有限元分析两种方式的命令流

用ansys对一平面桁架有限元分析两种方式的命令流 标签： ansys 有限元 命令流 2009-11-03 10:41
!ex1.1-平面桁架分析
!创建几个模型，再到有限元模型的分析过程命令流
!1.前处理
finish
/clear
/filname,truss,1
/title,the analysis of plane truss
/replot !重新显示
/prep7
k,1$k,2,6 !创建关键点，$为续行符，与另起一行效果相同。
k,3,12
k,4,18$k,5,24
k,6,6,8
k,7,12,8,0
k,8,18,8,0
l,1,2 !创建线
l,2,3
l,3,4$l,4,5$l,1,6$l,6,7$l,7,8
l,5,8
l,2,6$l,3,7$l,4,8$l,6,3$l,3,8
/pnum,kp,1 !设定显示关键点号
/pnum,line,1 !设定显示线号
lplot !绘制线
et,1,link1
r,1,0.01
r,2,0.005$r,3,0.0125
mp,ex,1,2.1e11 !定义材料属性，弹性模量
mp,prxy,1,0.3 !定义材料属性，泊松比
lsel,s,tan1,y !选择水平线
latt,1,1,1 !定义属性
lsel,s,loc,y,1,7 !选择竖杆
lsel,r,loc,x,6,18!选择中间斜杆
latt,1,2,1
lsel,s,loc,y,1,7$lsel,u,loc,x,6,18$latt,1,3,1!选择两边斜杆并定义属性
allsel,all !选择全部实体
/pnum,real,1 !设置显示实常数号
/replot !显示各线的实常数号
lesize,all,,,1 !定义各个线所划分的单元个数
lmesh,all
finish !退出prep7处理器
!2.加载和求解
/solu
antype,0
lplot !绘制线
dk,1,ux,,,,uy !约束关键点1的ux,uy
dk,5,uy
fk,6,fy,-200000
fk,8,fy,-200000
fk,2,fy,-400000
fk,3,fy,-400000
fk,4,fy,-400000
/pnum,real,0 !关闭实常数号显示
/pnum,line,0
/pnum,kp,0
/pbc,all,,1 !显示实体上的边界条件和荷载
/psymb,ldiv,-1 !关闭线划分单元属性显示
lplot
solve
finish
!3.后处理
/post1
pldisp !绘制变形图
etable,mforce,smisc,1 !定义单元轴力表
etable,mstress,ls,1 !定义单元应力表
plls,mforce,mforce,1 !绘制单元轴力图
plls,mstress,mstress,1
prrsol !列出支撑反力表
finish
!/exit,nosav

!ex1.2-平面桁架分析
!直接建立有限元模型的命令流
!1.前处理
finish
/clear
/filname,truss,1
/title,the analysis of plane truss
/replot !重新显示
/prep7
et,1,link1
r,1,0.01
r,2,0.005$r,3,0.0125
mp,ex,1,2.1e11 !定义材料属性，弹性模量
mp,prxy,1,0.3 !定义材料属性，泊松比

n,1$n,2,6 !创建关键点，$为续行符，与另起一行效果相同。
n,3,12
n,4,18$n,5,24
n,6,6,8
n,7,12,8,0
n,8,18,8,0
type,1$mat,1$real,1 !定义单元类型号为1、材料类型号为1、实常数号为1.
e,1,2$e,2,3$e,3,4$e,4,5$e,6,7$e,7,8 !定义单元
real,2
e,2,6$e,3,7$e,4,8$e,6,3$e,3,8
real,3
e,1,6$e,8,5
finish !退出prep7处理器
!2.加载和求解
/solu
antype,0
d,1,ux,,,,,uy !约束节点1的ux,uy
d,5,uy
f,6,fy,-200000
f,8,fy,-200000
f,2,fy,-400000
f,3,fy,-400000
f,4,fy,-400000
solve
finish
!3.后处理
/post1
pldisp !绘制变形图
etable,mforce,smisc,1

!定义单元轴力表
etable,mstress,ls,1 !定义单元应力表
plls,mforce,mforce,1 !绘制单元轴力图
plls,mstress,mstress,1
prrsol !列出支撑反力表
finish
!/exit,nosav